move xcode/ into tools/

tools/xcode/example/Cocoa/Cocoa-Info.plist

@@ -0,0 +1,34 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
+<plist version="1.0">
+<dict>
+	<key>CFBundleDevelopmentRegion</key>
+	<string>en</string>
+	<key>CFBundleExecutable</key>
+	<string>${EXECUTABLE_NAME}</string>
+	<key>CFBundleIconFile</key>
+	<string>logo.png</string>
+	<key>CFBundleIdentifier</key>
+	<string>org.sfml-dev.${PRODUCT_NAME:rfc1034identifier}</string>
+	<key>CFBundleInfoDictionaryVersion</key>
+	<string>6.0</string>
+	<key>CFBundleName</key>
+	<string>${PRODUCT_NAME}</string>
+	<key>CFBundlePackageType</key>
+	<string>APPL</string>
+	<key>CFBundleShortVersionString</key>
+	<string>1.0</string>
+	<key>CFBundleSignature</key>
+	<string>????</string>
+	<key>CFBundleVersion</key>
+	<string>1</string>
+	<key>LSMinimumSystemVersion</key>
+	<string>${MACOSX_DEPLOYMENT_TARGET}</string>
+	<key>NSHumanReadableCopyright</key>
+	<string>Copyright © 2007-2011 Marco Antognini and Laurent Gomila. Shared under zlib/libpng License.</string>
+	<key>NSMainNibFile</key>
+	<string>MainMenu</string>
+	<key>NSPrincipalClass</key>
+	<string>NSApplication</string>
+</dict>
+</plist>

tools/xcode/example/Cocoa/Cocoa-Prefix.pch

@@ -0,0 +1,7 @@
+//
+// Prefix header for all source files of the 'Cocoa' target in the 'Cocoa' project
+//
+
+#ifdef __OBJC__
+    #import <Cocoa/Cocoa.h>
+#endif

tools/xcode/example/Cocoa/CocoaAppDelegate.h

@@ -0,0 +1,59 @@
+////////////////////////////////////////////////////////////
+//
+// SFML - Simple and Fast Multimedia Library
+// Copyright (C) 2007-2011 Marco Antognini (antognini.marco@gmail.com), 
+//                         Laurent Gomila (laurent.gom@gmail.com), 
+//
+// This software is provided 'as-is', without any express or implied warranty.
+// In no event will the authors be held liable for any damages arising from the use of this software.
+//
+// Permission is granted to anyone to use this software for any purpose,
+// including commercial applications, and to alter it and redistribute it freely,
+// subject to the following restrictions:
+//
+// 1. The origin of this software must not be misrepresented;
+//    you must not claim that you wrote the original software.
+//    If you use this software in a product, an acknowledgment
+//    in the product documentation would be appreciated but is not required.
+//
+// 2. Altered source versions must be plainly marked as such,
+//    and must not be misrepresented as being the original software.
+//
+// 3. This notice may not be removed or altered from any source distribution.
+//
+////////////////////////////////////////////////////////////
+
+#import <Cocoa/Cocoa.h>
+#import <SFML/Graphics.hpp>
+
+/*
+ * NB : We need pointers for C++ objects fields in Obj-C interface !
+ *      The recomanded way is to use PIMP idiom.
+ *
+ *      It's elegant. Moreover, we do no constrain
+ *      other file including this one to be Obj-C++.
+ */
+
+struct SFMLmainWindow;
+
+@interface CocoaAppDelegate : NSObject <NSApplicationDelegate> {
+@private
+    NSWindow        *_window;
+    NSView          *_sfmlView;
+    NSTextField     *_textField;
+    SFMLmainWindow  *_mainWindow;
+    NSTimer         *_renderTimer;
+    BOOL             _visible;
+}
+
+@property (retain) IBOutlet NSWindow    *window;
+@property (assign) IBOutlet NSView      *sfmlView;
+@property (assign) IBOutlet NSTextField *textField;
+
+-(IBAction)colorChanged:(NSPopUpButton *)sender;
+-(IBAction)rotationChanged:(NSSlider *)sender;
+-(IBAction)visibleChanged:(NSButton *)sender;
+-(IBAction)textChanged:(NSTextField *)sender;
+-(IBAction)updateText:(NSButton *)sender;
+
+@end

tools/xcode/example/Cocoa/CocoaAppDelegate.mm

@@ -0,0 +1,199 @@
+////////////////////////////////////////////////////////////
+//
+// SFML - Simple and Fast Multimedia Library
+// Copyright (C) 2007-2011 Marco Antognini (antognini.marco@gmail.com), 
+//                         Laurent Gomila (laurent.gom@gmail.com), 
+//
+// This software is provided 'as-is', without any express or implied warranty.
+// In no event will the authors be held liable for any damages arising from the use of this software.
+//
+// Permission is granted to anyone to use this software for any purpose,
+// including commercial applications, and to alter it and redistribute it freely,
+// subject to the following restrictions:
+//
+// 1. The origin of this software must not be misrepresented;
+//    you must not claim that you wrote the original software.
+//    If you use this software in a product, an acknowledgment
+//    in the product documentation would be appreciated but is not required.
+//
+// 2. Altered source versions must be plainly marked as such,
+//    and must not be misrepresented as being the original software.
+//
+// 3. This notice may not be removed or altered from any source distribution.
+//
+////////////////////////////////////////////////////////////
+
+#import "CocoaAppDelegate.h"
+#import "NSString+stdstring.h"
+
+// These define are used for converting the color of the NSPopUpButton
+#define BLUE    @"Blue"
+#define GREEN   @"Green"
+#define RED     @"Red"
+
+// Our PIMPL
+struct SFMLmainWindow
+{
+    SFMLmainWindow(sf::WindowHandle win)
+    : renderWindow(win)
+    , background(sf::Color::Blue)
+    {
+        std::string resPath = [[[NSBundle mainBundle] resourcePath] tostdstring];
+        if (!logo.LoadFromFile(resPath + "/logo.png")) {
+            NSLog(@"Couldn't load the logo image");
+        }
+        
+        logo.SetSmooth(true);
+        
+        sprite.SetTexture(logo, true);
+        sprite.SetOrigin(sprite.GetSize() / 2.f);
+        sprite.Scale(0.3, 0.3);
+        
+        unsigned int ww = renderWindow.GetWidth();
+        unsigned int wh = renderWindow.GetHeight();
+        sprite.SetPosition(sf::Vector2f(ww, wh) / 2.f);
+        
+        text.SetColor(sf::Color::White);
+    }
+    
+    sf::RenderWindow    renderWindow;
+    sf::Text            text;
+    sf::Texture         logo;
+    sf::Sprite          sprite;
+    sf::Color           background;
+};
+
+// Private stuff
+@interface CocoaAppDelegate ()
+
+@property (assign) SFMLmainWindow   *mainWindow;
+@property (retain) NSTimer          *renderTimer;
+@property (assign) BOOL              visible;
+
+-(void)renderMainWindow:(NSTimer *)aTimer;
+
+@end
+
+
+// Finally, the implementation
+@implementation CocoaAppDelegate
+
+@synthesize window          = _window;
+@synthesize sfmlView        = _sfmlView;
+@synthesize textField       = _textField;
+
+@synthesize mainWindow      = _mainWindow;
+@synthesize renderTimer     = _renderTimer;
+@synthesize visible         = _visible;
+
+-(void)applicationDidFinishLaunching:(NSNotification *)aNotification
+{
+    // Init the 1st SFML render area.
+    self.mainWindow = new SFMLmainWindow(self.sfmlView);
+    self.mainWindow->text.SetString([self.textField.stringValue tostdwstring]);
+    self.visible = YES;
+    
+    // Launch the timer to periodically display our stuff into the Cocoa view.
+    self.renderTimer = [NSTimer timerWithTimeInterval:1.f/60.f
+                                               target:self
+                                             selector:@selector(renderMainWindow:)
+                                             userInfo:nil 
+                                              repeats:YES];
+	[[NSRunLoop mainRunLoop] addTimer:self.renderTimer
+                              forMode:NSDefaultRunLoopMode];
+	[[NSRunLoop mainRunLoop] addTimer:self.renderTimer
+                              forMode:NSEventTrackingRunLoopMode];
+    /*
+     * This is really some ugly code but in order to have the timer fired
+     * periodically we need to add it to the two above runloop mode.
+     *
+     * The default mode allows timer firing while the user doesn't do anything
+     * while the second mode allows timer firing while he is using a slider
+     * or a menu.
+     */
+}
+
+-(void)dealloc
+{
+    [self.renderTimer invalidate];
+    self.mainWindow->renderWindow.Close();
+    
+    self.window             = nil;
+    self.sfmlView           = nil;
+    self.textField          = nil;
+    
+    delete self.mainWindow;
+    self.mainWindow         = 0;
+    self.renderTimer        = nil;
+    
+    [super dealloc];
+}
+
+-(void)renderMainWindow:(NSTimer *)aTimer
+{
+    // Scaling
+    /* /!\ we do this at 60fps so choose low scaling factor! /!\ */
+    if (sf::Keyboard::IsKeyPressed(sf::Keyboard::Up))
+    {
+        self.mainWindow->sprite.Scale(1.01, 1.01);
+    }
+    if (sf::Keyboard::IsKeyPressed(sf::Keyboard::Down))
+    {
+        self.mainWindow->sprite.Scale(0.99, 0.99);
+    }
+    
+    // Clear the window, display some stuff and display it into our view.
+    
+    self.mainWindow->renderWindow.Clear(self.mainWindow->background);
+    
+    if (self.visible)
+    {
+        self.mainWindow->renderWindow.Draw(self.mainWindow->sprite);
+    }
+    
+    self.mainWindow->renderWindow.Draw(self.mainWindow->text);
+    
+    self.mainWindow->renderWindow.Display();
+}
+
+-(IBAction)colorChanged:(NSPopUpButton *)sender
+{
+    // Convert title to color
+    NSString *color = [[sender selectedItem] title];
+    if ([color isEqualToString:BLUE])
+    {
+        self.mainWindow->background = sf::Color::Blue;
+    } 
+    else if ([color isEqualToString:GREEN])
+    {
+        self.mainWindow->background = sf::Color::Green;
+    } 
+    else
+    {
+        self.mainWindow->background = sf::Color::Red;
+    }
+}
+
+-(IBAction)rotationChanged:(NSSlider *)sender
+{
+    float angle = [sender floatValue];
+    self.mainWindow->sprite.SetRotation(angle);
+}
+
+-(IBAction)visibleChanged:(NSButton *)sender
+{
+    self.visible = [sender state] == NSOnState;
+}
+
+-(IBAction)textChanged:(NSTextField *)sender
+{
+    self.mainWindow->text.SetString([[sender stringValue] tostdwstring]);
+}
+
+- (IBAction)updateText:(NSButton *)sender
+{
+    // Simply simulate textChanged :
+    [self textChanged:self.textField];
+}
+
+@end

tools/xcode/example/Cocoa/NSString+stdstring.h

@@ -0,0 +1,39 @@
+////////////////////////////////////////////////////////////
+//
+// SFML - Simple and Fast Multimedia Library
+// Copyright (C) 2007-2011 Marco Antognini (antognini.marco@gmail.com), 
+//                         Laurent Gomila (laurent.gom@gmail.com), 
+//
+// This software is provided 'as-is', without any express or implied warranty.
+// In no event will the authors be held liable for any damages arising from the use of this software.
+//
+// Permission is granted to anyone to use this software for any purpose,
+// including commercial applications, and to alter it and redistribute it freely,
+// subject to the following restrictions:
+//
+// 1. The origin of this software must not be misrepresented;
+//    you must not claim that you wrote the original software.
+//    If you use this software in a product, an acknowledgment
+//    in the product documentation would be appreciated but is not required.
+//
+// 2. Altered source versions must be plainly marked as such,
+//    and must not be misrepresented as being the original software.
+//
+// 3. This notice may not be removed or altered from any source distribution.
+//
+////////////////////////////////////////////////////////////
+
+#import <string>
+#import <Foundation/Foundation.h>
+
+@interface NSString (NSString_stdstring)
+
++(id)stringWithstdstring:(std::string const &)string;
+
++(id)stringWithstdwstring:(std::wstring const &)string;
+
+-(std::string)tostdstring;
+
+-(std::wstring)tostdwstring;
+
+@end

tools/xcode/example/Cocoa/NSString+stdstring.mm

@@ -0,0 +1,77 @@
+////////////////////////////////////////////////////////////
+//
+// SFML - Simple and Fast Multimedia Library
+// Copyright (C) 2007-2011 Marco Antognini (antognini.marco@gmail.com), 
+//                         Laurent Gomila (laurent.gom@gmail.com), 
+//
+// This software is provided 'as-is', without any express or implied warranty.
+// In no event will the authors be held liable for any damages arising from the use of this software.
+//
+// Permission is granted to anyone to use this software for any purpose,
+// including commercial applications, and to alter it and redistribute it freely,
+// subject to the following restrictions:
+//
+// 1. The origin of this software must not be misrepresented;
+//    you must not claim that you wrote the original software.
+//    If you use this software in a product, an acknowledgment
+//    in the product documentation would be appreciated but is not required.
+//
+// 2. Altered source versions must be plainly marked as such,
+//    and must not be misrepresented as being the original software.
+//
+// 3. This notice may not be removed or altered from any source distribution.
+//
+////////////////////////////////////////////////////////////
+
+#include <SFML/System/Utf.hpp>
+
+@implementation NSString (NSString_stdstring)
+
++(id)stringWithstdstring:(std::string const &)string
+{
+    std::string utf8;
+    utf8.reserve(string.size() + 1);
+    
+    sf::Utf8::FromAnsi(string.begin(), string.end(), std::back_inserter(utf8));
+    
+    NSString *str = [NSString stringWithCString:utf8.c_str() 
+                                       encoding:NSUTF8StringEncoding];
+    return str;
+}
+
+-(std::string)tostdstring
+{
+    // Not sure about the encoding to use. Using [self UTF8String] doesn't
+    // work for characters like é or à.
+    const char *cstr = [self cStringUsingEncoding:NSISOLatin1StringEncoding];
+    
+    if (cstr != NULL)
+    {
+        std::string str(cstr);
+        return str;
+    }
+    else
+    {
+        return "";
+    }
+}
+
++(id)stringWithstdwstring:(std::wstring const &)string
+{
+    char* data = (char *)string.data();
+    unsigned size = string.size() * sizeof(wchar_t);
+    
+    NSString *str = [[[NSString alloc] initWithBytes:data length:size
+                                            encoding:NSUTF32LittleEndianStringEncoding] autorelease];
+    return str;
+}
+
+-(std::wstring)tostdwstring
+{
+    // According to wikipedia, Mac OS X is Little Endian on x86 and x86-64
+    // http://en.wikipedia.org/wiki/Endianness
+    NSData* asData = [self dataUsingEncoding:NSUTF32LittleEndianStringEncoding];
+    return std::wstring((wchar_t *)[asData bytes], [asData length] / sizeof(wchar_t));
+}
+
+@end

tools/xcode/example/Cocoa/en.lproj/Credits.rtf

@@ -0,0 +1,7 @@
+{\rtf1\ansi\ansicpg1252\cocoartf1038\cocoasubrtf360
+{\fonttbl\f0\fswiss\fcharset0 Helvetica;}
+{\colortbl;\red255\green255\blue255;}
+\paperw11900\paperh16840\vieww9600\viewh8400\viewkind0
+\pard\tx560\tx1120\tx1680\tx2240\tx2800\tx3360\tx3920\tx4480\tx5040\tx5600\tx6160\tx6720\qj\pardirnatural
+
+\f0\fs24 \cf0 See http://sfml-dev.org for more information}

tools/xcode/example/Cocoa/en.lproj/InfoPlist.strings

@@ -0,0 +1,2 @@
+/* Localized versions of Info.plist keys */
+

tools/xcode/example/Cocoa/main.m

@@ -0,0 +1,31 @@
+////////////////////////////////////////////////////////////
+//
+// SFML - Simple and Fast Multimedia Library
+// Copyright (C) 2007-2011 Marco Antognini (antognini.marco@gmail.com), 
+//                         Laurent Gomila (laurent.gom@gmail.com), 
+//
+// This software is provided 'as-is', without any express or implied warranty.
+// In no event will the authors be held liable for any damages arising from the use of this software.
+//
+// Permission is granted to anyone to use this software for any purpose,
+// including commercial applications, and to alter it and redistribute it freely,
+// subject to the following restrictions:
+//
+// 1. The origin of this software must not be misrepresented;
+//    you must not claim that you wrote the original software.
+//    If you use this software in a product, an acknowledgment
+//    in the product documentation would be appreciated but is not required.
+//
+// 2. Altered source versions must be plainly marked as such,
+//    and must not be misrepresented as being the original software.
+//
+// 3. This notice may not be removed or altered from any source distribution.
+//
+////////////////////////////////////////////////////////////
+
+#import <Cocoa/Cocoa.h>
+
+int main(int argc, char *argv[])
+{
+    return NSApplicationMain(argc, (const char **)argv);
+}